windows10 不要なサービスを一括で停止無効化するプログラム


windows10 にアップデートしたらわけのわからないサービスがたくさんうごいてて、いままで快適だったPCが重くてしょうがない。

なんで、こんなサービス勝手にうごいてるんだ?

まあ、いちいちネットで調べながら、停止&無効化してたけど
今度 windowsクラッシュして 再インストール
したら、また最初から・・・

ついでに皆さまのためにもツールを作ろうってことで、
サービス名からkey名を検索して、停止するためのバッチを作成する vbsをつくりました。
‘停止サービスセット
arrStopList.Add(“Bluetooth サポート サービス”)
arrStopList.Add(“Contact Data”)
・・・
を適当に入れてますが

https://mikasaphp.net/win10serviceoff.html
など参考に自分の環境に合わせて追加削除してください

テキストに張り付けて xxxx.vbs vbs拡張子をつけて保存すれば
ダブルクリックで実行できます
実行すると
デスクトップに ”サービス一覧.txt”と”サービスの停止コマンドバッチ.bat”ができます
“サービスの停止コマンドバッチ.bat”を右クリックして「管理者として実行」をすると
サービス停止コマンドが実行されます
“サービスの停止コマンドバッチ.bat”
のなかには
・サービス名(コメント)
・停止コマンド
・無効化コマンド(コメント)
となっていますので、最初は停止だけしか実行されません
(停止してもwindowsを再起動すると復活します)
しばらく使ってみて問題のないサービスは
・無効化コマンド(コメント)の先頭の「:」を外して実行すれば
無効化されます。

ダウンロード(右クリック 名前を付けてリンク先を保存)
stopservice.vbs_.txt
(vbs ダウンロードは セキュリティ上 ブロックされる可能性があるため 拡張子 _.txt になっています)
ダウンロード後に変更してください)

'

Set objShell = CreateObject("WScript.Shell")
'ファイル設定
'サービス一覧
keyfile = objShell.SpecialFolders("Desktop") & "\" & "サービス一覧.txt"
'コマンド出力
stopbat = objShell.SpecialFolders("Desktop") & "\" & "サービスの停止コマンドバッチ.bat"

'サービス一覧の取得
cmd ="%ComSpec% /c sc queryex state= all > " & """" & keyfile & """"
objShell.run cmd ,0,True

Set objFso = CreateObject("Scripting.FileSystemObject")
Set objFile = objFso.OpenTextFile(keyfile, 1, False)

'サービス一覧配列
Dim arrKeyList
Set arrKeyList = CreateObject("System.Collections.ArrayList")
'ストップサービス一覧
Dim arrStopList
Set arrStopList = CreateObject("System.Collections.ArrayList")
'出力コマンド
Dim arrStopTarget
Set arrStopTarget = CreateObject("System.Collections.ArrayList")

If Err.Number > 0 Then
    WScript.Echo "Open Error"
Else
    Do Until objFile.AtEndOfStream
        arrKeyList.add(objFile.ReadLine)' & vbCrLf
    Loop
End If

'停止サービスセット
arrStopList.Add("Bluetooth サポート サービス")
arrStopList.Add("Contact Data")
arrStopList.Add("データ使用状況")
arrStopList.Add("ホストの同期")
arrStopList.Add("Client License Service (ClipSVC)")
arrStopList.Add("Microsoft Account Sign-in Assistant")
arrStopList.Add("Windows ストア インストール サービス")
arrStopList.Add("Windows Error Reporting Service")
arrStopList.Add("Connected Devices Platform Service")
arrStopList.Add("Connected Devices Platform ユーザー サービス")
arrStopList.Add("Connected User Experiences and Telemetry")
arrStopList.Add("MessagingService")
arrStopList.Add("Xbox Accessory Management Service")
arrStopList.Add("Xbox Game Monitoring")
arrStopList.Add("Xbox Live Auth Manager")
arrStopList.Add("Xbox Live セーブ データ")
arrStopList.Add("Xbox Live ネットワーキング サービス")
arrStopList.Add("User Data Storage")
arrStopList.Add("User Data Access")
arrStopList.Add("Windows プッシュ通知システム サービス")
arrStopList.Add("Windows プッシュ通知ユーザー サービス")


'稼動サービスキー名確認
For s=0 To arrStopList.count-1

  For i=0 To arrKeyList.count-1
  keyStopStr ="DISPLAY_NAME: " & arrStopList(s)
     if inStr(arrKeyList(i), keyStopStr)>0 then
     		servkey =mid(arrKeyList(i-1),15)
      arrStopTarget.add(":" & arrStopList(s))
      arrStopTarget.add("sc stop " & servkey)
      arrStopTarget.add(":sc config " & """" & servkey & """" & " start= disabled " )
      arrStopTarget.add("" )
     end if
  Next
Next

'停止コマンドバッチ書き出し
if arrStopTarget.count >0 then
  Set tso = objFso.OpenTextFile(stopbat, 2, true)
  For i=0 To arrStopTarget.count-1
    tso.WriteLine(arrStopTarget(i))
  next
  tso.WriteLine("Pause")
  tso.Close
  Wscript.echo "停止対象サービスの停止コマンドバッチを(デスクトップに)作成しました" & vbCrLf & "みあたらないときはF5を押してみてください"

else
  Wscript.echo "停止対象サービスはありません"
end if

objFile.Close
Set objFile = Nothing
Set objFso = Nothing

基本操作、メール、インターネット、写真、動画、音楽、アプリ活用、印刷、便利設定ほか、厳選テクニック&解説652。Windowsのすべてがこの一冊に!Anniversary Updateに対応。基本操作から便利なテクニックまで、こんな本がほしかった!全機能解説のスタンダード。ネットワークを究める。企業レベルの設定&カスタマイズをあなたに。気になる新操作がスムーズにわかる。最初に電源を入れるところから説明。メールを設定する手順も詳しく説明。新しいメニュー画面の使い方を詳解。Windows10の歴史やシステム、魅力的でかつ難解な仕様や機能、時には問題点にまで切り込んで、その特性を踏まえたカスタマイズや使いこなしを解説。全操作、全機能が載ってるから迷わない!基本から便利技・トラブル対応まで全部わかる!基本の操作から最新アプリ、昔ながらの操作も全部できる!はじめてのタッチ操作、はじめてのWindows10の人も安心!わかりやすい索引で「あれがしたい」「これがしたい」から探せる、側にあれば安心な1冊!自由自在にWindows10を操ろう。各項目は操作手順に沿って解説!!タッチ/クリック操作の違いもわかるので、PCユーザーもSurfaceユーザーも安心!!索引や関連項目参照も豊富!!「ここが知りたい」「こんなときどうする?」と思ったら即座に引ける!!Microsoft MVPだからわかる操作のポイントを伝授!!新機能から基本操作、各種応用Tipsまでを手取り足取り完全ガイド!!いちばんやさしいWindows10の本です。見やすい画面とていねいな解説で初心者でも思い通りに操作できる!この一冊で必要な機能は十分!基本操作はもちろん使いこなし技も満載!知っておきたい操作と快適な設定を完全解説!!Windows10の基本的な使い方から、便利なテクニック、基本アプリの楽しみ方まで大きな文字でわかりやすく解説!

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です